x11-wm/phoc: add 0.33.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

x11-wm/phoc/Manifest

@@ -1,2 +1,3 @@
+DIST phoc-0.33.0.tar.xz 646148 BLAKE2B 74e6ac8eec5a37a9dd255d48b1bca65f992399eeb9dc19b22bb84e746f7cae95306c0a487aae828d939be2a0736408476aba6b947c1f44d825340bfcb1873d49 SHA512 7907c116b426383843b6782bafe5f416e7cb8b4039c9ee81ace35476df3b4d0ef92a968f57edef91094cd28387ceff03f1cdd802de65e0e9e3840eab03a78ac9
 DIST phoc-v0.13.1.tar.gz 166867 BLAKE2B 6606855efe7099d12c8be3ee16c401bbcc618aaed2f264abe982cc4a49ccbc0e65fac1b7d8da62de4261bdf3a322f4313a15723c7b7cb7a9ce279957dbf89c78 SHA512 0da68ac4d0601e91ed5f59eeb0beea64180b546f58b300631495084d366fe515c26fe9d58d0ca20687032f6824ae98dcc82edd8a6c80caa95178d24d27ee2650
 DIST wlroots-c9cd3502ba6113070020de50e41f0af72e0f5031.tar.gz 506612 BLAKE2B 70589e63cf223aa5b3634e057cc8c9d1f52d0f6c0fd3bbf66739bc1c934036bab0e8fc8337f51b1d4bb0d73c008b16421c354194cf215741e84ad88345465870 SHA512 af610233ec2343a3baefbb30db4b9a3f30dac4f8656293849be603fbcad0cdd65e91d80702c35e4aaf47437e8c301229c4933b7c8b5df3a7128979c94bcfcddc

x11-wm/phoc/phoc-0.33.0.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson virtualx xdg
+
+DESCRIPTION="Wayland compositor for mobile phones"
+HOMEPAGE="https://gitlab.gnome.org/World/Phosh/phoc"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz"
+
+LICENSE="|| ( GPL-3+ MIT ) GPL-3+ LGPL-2.1+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="+X gtk-doc man test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/glib-2.70:2
+	dev-libs/json-glib
+	dev-libs/libinput:=
+	dev-libs/wayland
+	>=gnome-base/gnome-desktop-3.26:3
+	gnome-base/gsettings-desktop-schemas
+	>=gui-libs/wlroots-0.16.0:=[X?]
+	<gui-libs/wlroots-0.17.0
+	media-libs/libglvnd
+	x11-libs/libdrm
+	x11-libs/pixman
+	x11-libs/libxkbcommon[X?,wayland]
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-libs/glib:2
+	dev-libs/wayland-protocols
+	dev-util/wayland-scanner
+	sys-devel/gettext
+	gtk-doc? ( dev-util/gi-docgen )
+	man? ( dev-python/docutils )
+	test? ( x11-wm/mutter )
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature X xwayland)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man)
+		$(meson_use test tests)
+		-Dembed-wlroots=disabled
+	)
+	meson_src_configure
+}
+
+src_test() {
+	local -x LC_ALL="C.UTF-8"
+	local -x WLR_RENDERER="pixman"
+
+	virtx meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	newbin helpers/auto-maximize phoc-auto-maximize
+	newbin helpers/scale-to-fit phoc-scale-to-fit
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}