net-misc/cellbroadcastd: new package, add 0.0.2

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

net-misc/cellbroadcastd/Manifest

@@ -0,0 +1,2 @@
+DIST cbd-0.0.2.tar.xz 69388 BLAKE2B 9dcd854fe72e8b76e2a4c95e69c7a43f0e096f7c0abbdf7ec217d26bbeb73dfa2bcd5dfac162735e15e676e40882a385f87c82a1b01905565d3962fe26b4bb9a SHA512 672b0fbbf5201bff259886657917521c6323611be668e571031188d929e3a2bfd5fd96735b05f6a204e9745fb49ab1a492150cae5d2346898ab1b064d4181374
+DIST cbd-0.0.2.tar.xz.asc 833 BLAKE2B d710158df396aafbaa272a8a670f8d682ce29962d8a215a6f847c619a0934464a0664c22e4eb2b106a1f6083fb8d77b87deba01caf78dd2171c59eaa864b4574 SHA512 a7ff8d9228b633ca38c2823c6ff241c4fe30b632f5576a3ff3c6e65dc82dba7f9ee92dba3382d77d7905b145de2cb84969de4ea050b6b4d045a4341af7eb3b2e

net-misc/cellbroadcastd/cellbroadcastd-0.0.2.ebuild

@@ -0,0 +1,52 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson systemd verify-sig
+
+DESCRIPTION="DBus service for cellular broadcast messages"
+HOMEPAGE="https://gitlab.freedesktop.org/devrtz/cellbroadcastd"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/cbd-${PV}.tar.xz
+	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/cbd-${PV}.tar.xz.asc )"
+S="${WORKDIR}/cbd-${PV}"
+
+LICENSE="GPL-3+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+introspection"
+
+DEPEND="
+	>=dev-libs/glib-2.76.0:2
+	>=dev-libs/gmobile-0.4.0
+	gnome-base/gsettings-desktop-schemas
+	net-misc/mobile-broadband-provider-info
+	>=net-misc/modemmanager-1.24.0:=
+	sys-apps/dbus
+	introspection? ( dev-libs/gobject-introspection )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	sys-devel/gettext
+	verify-sig? ( sec-keys/openpgp-keys-phosh )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/phosh.asc"
+
+src_configure() {
+	local emesonargs=(
+		-Ddaemon=true
+		-Dtests=true
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+		$(meson_feature introspection)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	find "${ED}"/usr/$(get_libdir) -name "*.a" -delete || die
+}

net-misc/cellbroadcastd/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="freedesktop-gitlab">devrtz/cellbroadcastd</remote-id>
+	</upstream>
+</pkgmetadata>