media-plugins/clapper-enhancers: new package, add 0.10.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

media-plugins/clapper-enhancers/Manifest

@@ -0,0 +1 @@
+DIST clapper-enhancers-0.10.0.tar.gz 74614 BLAKE2B d100f32130bb52e043b07a00c2ac408cb605c39d60af037015c8adf10ff82cf3fdbf9fb22ac617d99b80362347a64cb06215843b6a924a34bcbedaeb6b5f952b SHA512 dad8adb725dae0f69e0ac46855343a196308737ba2069c4a696a6d62d8f29469b168c1b19e0cdef1e7f9405eeafde53a3718ff0287caf92b5a70ca32c777ec5c

media-plugins/clapper-enhancers/clapper-enhancers-0.10.0.ebuild

@@ -0,0 +1,72 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..14} )
+inherit gnome2-utils meson python-single-r1
+
+DESCRIPTION="Plugins enhancing Clapper library capabilities"
+HOMEPAGE="https://github.com/Rafostar/clapper-enhancers"
+SRC_URI="https://github.com/Rafostar/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+control-hub +http +mpris +sqlite3 +youtube"
+REQUIRED_USE="youtube? ( ${PYTHON_REQUIRED_USE} )"
+
+DEPEND="
+	>=dev-libs/glib-2.76:2
+	dev-libs/libpeas:2
+	>=media-libs/gstreamer-1.20.0:1.0
+	>=media-video/clapper-0.10.0
+	control-hub? (
+		net-libs/libsoup:3.0
+		>=net-libs/libmicrodns-0.2.0:=
+	)
+	http? (
+		>=dev-libs/json-glib-1.2.0
+		net-libs/libsoup:3.0
+	)
+	sqlite3? ( dev-db/sqlite:3 )
+"
+RDEPEND="${DEPEND}
+	youtube? (
+		${PYTHON_DEPS}
+		dev-libs/libpeas:2[python,${PYTHON_SINGLE_USEDEP}]
+		media-video/clapper[introspection]
+		$(python_gen_cond_dep '
+			dev-python/pygobject:3[${PYTHON_USEDEP}]
+			net-misc/yt-dlp[${PYTHON_USEDEP}]
+		')
+	)
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/glib:2
+	virtual/pkgconfig
+	mpris? ( dev-util/gdbus-codegen )
+"
+
+src_configure() {
+	local emesonargs=(
+		--auto-features=enabled
+		$(meson_feature control-hub)
+		$(meson_feature http lbry)
+		$(meson_feature http peertube)
+		$(meson_feature mpris)
+		$(meson_feature sqlite3 recall)
+		$(meson_feature youtube yt-dlp)
+	)
+
+	meson_src_configure
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}

media-plugins/clapper-enhancers/metadata.xml

@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">Rafostar/clapper-enhancers</remote-id>
+	</upstream>
+	<use>
+		<flag name="control-hub">Build the Clapper Enhancer Control Hub plugin</flag>
+		<flag name="http">Enable plugins that use network</flag>
+		<flag name="mpris">Build the Clapper Enhancer MPRIS plugin</flag>
+		<flag name="sqlite3">Build the Clapper Enhancer Recall plugin</flag>
+		<flag name="youtube">Enable YouTube support via <pkg>net-misc/yt-dlp</pkg></flag>
+	</use>
+</pkgmetadata>