media-sound/Tauon: add 9.1.0

Signed-off-by: David Roman <davidroman96@gmail.com>

media-sound/Tauon/Manifest

@@ -1,2 +1,3 @@
 DIST Tauon-8.2.3.tar.gz 1728107 BLAKE2B 2f53c700dd3b2b121daa44ee94c4e437ad1ae21d3eb3911a4bba110ce7255e555fa0532803c2aac709df4b21f2d6ca6773df1ba5ae69ced225cedc9dbaff8f7a SHA512 4bf8113565f2c5b767725c65bcf79b54f382a9a72efbf62b0fa3d7ca100b9fa242d83086c4af65f28bccdaf702a6935ef1079e77148b3d5c1857c068d62f6617
 DIST Tauon-9.0.0.tar.gz 1760312 BLAKE2B 54717ed9ee7bfae93fc1857c81230dcbb8f1a364a0b8a19d7fb3d7ee3df0b2be3581651aafce8e7921d96b3b4026072f394d8633da2281752f0ad14f399d665c SHA512 52f5eba2360d60493c79831a00f85a712a7405ef644dc7b5bfbcf60853bc474745bf563c0e1630cbc3becfda0e82aec8fbb308b06f0b655231e360ed92ec66b5
+DIST Tauon-9.1.0.tar.gz 1768827 BLAKE2B 0d4a8447a2af3c113c6d1c3fe4c6c26d654e6ad00125c724410f92cf456f7879ca543478b2b5f9516100ec871a1621a956c7c2bc3e0727a64914f12d134d06bc SHA512 3626b37ccbfdad38ed035a4efeaa2a3e4c125373c78716fd72b25d30ce81b41095d3fe6b7d8200b821791903b19638b0e9795c761175f206bb0097b9ec41b819

media-sound/Tauon/Tauon-9.1.0.ebuild

@@ -0,0 +1,110 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PLOCALES="cs de es fr_FR hu id it ja_JP nb_NO pl pt pt_BR pt_PT ru sv tr zh_CN"
+
+PYTHON_COMPAT=( python3_{12..13} )
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit desktop distutils-r1 optfeature plocale xdg
+
+DESCRIPTION="The desktop music player of today!"
+HOMEPAGE="https://tauonmusicbox.rocks/"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_SUBMODULES=()
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Taiko2k/${PN}"
+else
+	SRC_URI="https://github.com/Taiko2k/Tauon/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+PHAZOR_DEPS="
+	dev-libs/miniaudio
+	media-libs/flac:=
+	media-libs/game-music-emu
+	media-libs/libopenmpt
+	media-libs/opus
+	media-libs/opusfile
+	media-libs/libsamplerate
+	media-libs/libvorbis
+	media-sound/mpg123
+	media-sound/wavpack
+	sci-libs/kissfft[-cpu_flags_x86_sse]
+"
+
+DEPEND="
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/musicbrainzngs[${PYTHON_USEDEP}]
+	dev-python/natsort[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pyopengl[${PYTHON_USEDEP}]
+	dev-python/pysdl3[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setproctitle[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	dev-python/unidecode[${PYTHON_USEDEP}]
+	media-video/ffmpeg
+	media-libs/mutagen[${PYTHON_USEDEP}]
+	media-libs/sdl3-image
+
+	${PHAZOR_DEPS}
+"
+
+RDEPEND="
+	${DEPEND}
+
+	dev-libs/libayatana-appindicator
+	media-sound/mpg123-base
+	x11-libs/libnotify
+"
+
+BDEPEND="sys-devel/gettext"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-7.9.0-phazor-build.patch"
+	"${FILESDIR}/${PN}-8.1.0-fix-locale-path.patch"
+)
+
+src_compile() {
+	distutils-r1_src_compile
+
+	build_locale() {
+		msgfmt -o "locale/${1}/LC_MESSAGES/tauon.mo" "locale/${1}/LC_MESSAGES/tauon.po" || die
+	}
+
+	plocale_for_each_locale build_locale
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	install_locale() {
+		insinto "/usr/share/locale/${1}/LC_MESSAGES"
+		doins "locale/${1}/LC_MESSAGES/tauon.mo"
+	}
+
+	plocale_for_each_locale install_locale
+
+	sed -i 's/Exec=tauon/Exec=tauonmb/g' extra/tauonmb.desktop || die
+	domenu extra/tauonmb.desktop
+	doicon -s scalable extra/tauonmb.svg
+
+}
+
+pkg_postinst() {
+	optfeature "Chinese searches support" app-i18n/opencc[python]
+	optfeature "last fm support" dev-python/pylast
+	optfeature "PLEX support" dev-python/plexapi
+	optfeature "Spotify support" dev-python/tekore
+	optfeature "Discord Rich Presence support" dev-python/pypresence
+
+	xdg_pkg_postinst
+}