gui-libs/mir: add 2.21.1

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>

gui-libs/mir/Manifest

@@ -1,2 +1,3 @@
 DIST mir-2.20.1.tar.gz 6823288 BLAKE2B 68068f7f70eaacdf5840fe8c0bd65b0941240ede6850fc0fde80d894b1309a3f9741d7f28b399bdc453ab06954d1747dee5a9dc4561fe98236473c82cf334d65 SHA512 0e384200790aa025b0cc46d615adcf461b7a0a7dd1ca8429f023d5eeb6c9edf02aa099882c081d63635a55f7bd650b44d2c4294331fd04ce703be806ea866bb3
 DIST mir-2.20.2.tar.gz 6829935 BLAKE2B fcbd1608960cd67c94b56e1845f989e77eae10bd608b25b19887ab8f92ed388b960bb973d6639d1a794847d18ac3af9ff5e8a98d775b00388aaace3f43f46914 SHA512 f886e4fe561a96524cd45b4e84ce52241980aefd4edca8b01519ec790546a4a04b6e04fd79cca97e158c4b6bb94b0d0a281ae615c4574685b53fc38b2a0bb3ab
+DIST mir-2.21.1.tar.gz 6879903 BLAKE2B 644d41be226b7ecf673b26bcc14b52d693b11bc2d63775f591e7332d854b0d3725ca23a0747e7ea53b2928ea5f3221376d74fd6b5aea0997f392e2892028a12e SHA512 36bfef3462e2428d608e5b6e4ba910d4c0c1db6d4614cc46ebb322314230b785e308b120bf5a69e60aad6c6e04c369a48d7323cccc1d4a389dc757c69ffcff40

gui-libs/mir/mir-2.21.1.ebuild

@@ -0,0 +1,83 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="Set of libraries for building Wayland based shells"
+HOMEPAGE="https://mir-server.io/"
+SRC_URI="https://github.com/canonical/mir/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="|| ( GPL-2 GPL-3 ) || ( LGPL-2.1 LGPL-3 )"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="test X"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/glibmm:2
+	dev-cpp/libxmlpp:2.6
+	dev-cpp/yaml-cpp:=
+	dev-libs/boost:=
+	dev-libs/glib:2
+	dev-libs/libinput:=
+	dev-libs/wayland
+	dev-util/lttng-ust:=
+	media-libs/freetype
+	media-libs/libepoxy
+	media-libs/libglvnd
+	media-libs/mesa
+	sys-apps/util-linux
+	x11-libs/libXcursor
+	x11-libs/libdrm
+	x11-libs/libxcb:=
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	virtual/libudev:=
+	X? ( x11-libs/libX11 )
+"
+DEPEND="
+	${RDEPEND}
+	media-libs/glm
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+	test? (
+		dev-cpp/gtest
+		dev-util/umockdev
+		x11-base/xwayland
+	)
+"
+
+PATCHES=(
+	# bug 932786
+	"${FILESDIR}/${PN}-2.17.0-remove-debug-flags.patch"
+	"${FILESDIR}/${PN}-2.20.0-remove-tests.patch"
+)
+
+src_prepare() {
+	cmake_src_prepare
+	cmake_comment_add_subdirectory examples/ examples/tests/
+}
+
+src_configure() {
+	local platforms="gbm-kms;atomic-kms;wayland"
+	use X && platforms="${platforms};x11"
+
+	local mycmakeargs=(
+		# wlcs is not packaged
+		-DMIR_ENABLE_WLCS_TESTS=OFF
+		-DMIR_ENABLE_TESTS="$(usex test)"
+		-DMIR_FATAL_COMPILE_WARNINGS=OFF
+		-DMIR_PLATFORM="${platforms}"
+	)
+	use test && mycmakeargs+=(
+		# likely will not work in build environment
+		-DMIR_BUILD_PERFORMANCE_TESTS=OFF
+		-DMIR_BUILD_PLATFORM_TEST_HARNESS=OFF
+		-DMIR_BUILD_UNIT_TESTS=OFF
+	)
+	cmake_src_configure
+}