gui-apps/fuzzel: add 1.14.1

add verify-sig
mv tllist and wayland-protocols from bdep to depend
since 1.11.0, cairo is automagic, but it's no longer used for rounded
corner (see README) and not required w/ nanosvg. So it's disabled.
Note that upstream prefer resvg.

Closes: https://bugs.gentoo.org/945219
Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr>

gui-apps/fuzzel/Manifest

@@ -1 +1,3 @@
 DIST fuzzel-1.13.1.tar.gz 501037 BLAKE2B 01fd39d40661edc06872c31738aa5af4fc18ae71438b7e61e7987099dea4706438ca36008982bdab7a64fb1448ebb612ac5cb3d6e8aa43df90c3597522184d66 SHA512 dea1dd056df4928ffad08991149224d21a7aaa430de62dffb31601419cfae3ad420fdb8fe607a6d5ee8fd58c14024ea3d8249dc6c02fa68c0f38b60038de06be
+DIST fuzzel-1.14.1.tar.gz 511630 BLAKE2B 11189f015418bdf6f87054c70aa9b162e10ddd6f9977e6f606c9a1579931e0a7712933a3ee949227243c5d32c05dbd84d0039b54b95034f55ba705f9285bf2ad SHA512 efa288fcf2e54b26d9eddd017cbb33d6387bd0ffc71c6e5b6523a4e33beae9ce156cce4ef6cc167df2934515f6fe26dd6d3c6cd9cb301be178f9d0aaeced0fcf
+DIST fuzzel-1.14.1.tar.gz.sig 584 BLAKE2B e8c9a7daded3c7fe1a727177eb8013360232f8568dbf4e6edbfe35a686231ab9ea4c4f4f9947f32b2371e513bdf02d39915f3365dfe6e3b18937b43eee07b200 SHA512 373ad61fd5fd58632611a2b971647f0ad3205d9755ec4d70df4ff1d71be52055e5dd89b4c88f42002ad7264d07ab2350662e4f7eaf21dded49a6284df9faac97

gui-apps/fuzzel/fuzzel-1.14.1.ebuild

@@ -0,0 +1,62 @@
+# Copyright 2022-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson verify-sig
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://codeberg.org/dnkl/fuzzel.git"
+else
+	SRC_URI="
+		https://codeberg.org/dnkl/fuzzel/releases/download/${PV}/${P}.tar.gz
+		verify-sig? ( https://codeberg.org/dnkl/fuzzel/releases/download/${PV}/${P}.tar.gz.sig )
+	"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Application launcher for wlroots based Wayland compositors."
+HOMEPAGE="https://codeberg.org/dnkl/fuzzel"
+LICENSE="MIT"
+SLOT="0"
+IUSE="png svg"
+
+RDEPEND="
+	dev-libs/wayland
+	<media-libs/fcft-4.0.0
+	>=media-libs/fcft-3.3.1
+	media-libs/fontconfig
+	x11-libs/libxkbcommon
+	>=x11-libs/pixman-0.46.0
+	png? ( media-libs/libpng:= )
+	svg? ( media-libs/nanosvg )
+"
+DEPEND="
+	${RDEPEND}
+	>=dev-libs/tllist-1.0.1
+	>=dev-libs/wayland-protocols-1.41
+"
+BDEPEND="
+	app-text/scdoc
+	dev-util/wayland-scanner
+	verify-sig? ( sec-keys/openpgp-keys-dnkl )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dnkl.asc
+
+src_configure() {
+	local emesonargs=(
+		# cairo is not required with nanosvg
+		-Denable-cairo=disabled
+		-Dpng-backend=$(usex png libpng none)
+		-Dsvg-backend=$(usex svg nanosvg none)
+		$(meson_feature svg system-nanosvg)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	rm -rf "${ED}/usr/share/doc/fuzzel" || die
+}