media-sound/libcava: add 1.0.0

Signed-off-by: Ceres <ceres@ceressees.dev>

media-sound/libcava/Manifest

@@ -1 +1,2 @@
 DIST libcava-0.10.7.tar.gz 3341992 BLAKE2B 147a9e9b7700300b018faffa9684ce680b9e2e5a5c8554bb3057e408b755d13981a9e461ea56e388bb9804bbc27905d5730fc690e3687f637bceb4a59a66f8e3 SHA512 d8ec3d4bde04c06286e44d52b7a4dcbe48e94e6b1f94cfa0756e9c4933679a16ca7f256ccb43d5e9a75efeea06ccca55da79e84853c87207374cc6f451c624aa
+DIST libcava-1.0.0.tar.gz 3360785 BLAKE2B 4d3f0f8996f0d6a552b4a8eff259b48a875169bede7bf6642567d21c5a2d3824ee3f0c218408dd1759be711bc99de76f587689b1e3482f25564ce8392b62587a SHA512 55ceda98a6b2ec91f0aed39224bbe9f5cbb92118fc77ba908d3389eaa6c507d8e5dcca89680433ed7916ebd595a16fcd6f306ce8b66da30064b670b99a652c39

media-sound/libcava/libcava-1.0.0.ebuild

@@ -0,0 +1,67 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="Console-based Audio Visualizer for Alsa"
+HOMEPAGE="https://github.com/LukashonakV/cava/"
+SRC_URI="https://github.com/LukashonakV/cava/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+S="${WORKDIR}/cava-${PV}"
+
+LICENSE="MIT Unlicense"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="alsa jack +ncurses pipewire portaudio pulseaudio sdl sndio"
+
+RDEPEND="
+	dev-libs/iniparser
+	sci-libs/fftw:3.0=
+	alsa? ( media-libs/alsa-lib )
+	jack? ( virtual/jack )
+	ncurses? ( sys-libs/ncurses:= )
+	pipewire? ( media-video/pipewire:= )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	sdl? (
+		media-libs/libglvnd
+		media-libs/libsdl2[opengl,video]
+	)
+	sndio? ( media-sound/sndio:= )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+
+	echo ${PV} > version || die
+	eautoreconf
+}
+
+src_configure() {
+	filter-lto
+	append-flags -fno-strict-aliasing
+
+	econf --disable-cava-font
+}
+
+src_install() {
+	mkdir -p "${D}/usr/include/cava"
+	default
+	find "${ED}" -type f -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		elog "A default ~/.config/cava/config will be created after initial"
+		elog "use of ${PN}, see it and ${EROOT}/usr/share/doc/${PF}/README*"
+		elog "for configuring audio input and more."
+	elif ver_test ${REPLACING_VERSIONS##* } -lt 0.9; then
+		elog "If used, the noise_reduction config option in ~/.config/cava/config needs"
+		elog "to be updated from taking a float to integer (e.g. replace 0.77 with 77)."
+	fi
+}