media-sound/shortwave: add 5.1.0

Signed-off-by: Alexander Tsoy <alexander@tsoy.me>
2026-10-12 17:51:11 -04:00 · 2026-04-19 20:33:22 +03:00
1 parent 9c7c9d9720
commit a963e02fa3
@@ -1,2 +1,4 @@
 DIST Shortwave-5.0.0-crates.tar.xz 44879168 BLAKE2B f773ce84d130eb784ebf4be22ba493433c3b88133202345c7f8f11f58baa825d02dedb2b9cef2a423264a2fab82f6cd00a3bcbeeae0fadb55ae9284c4f52c30e SHA512 0a14840250ffcff22a6af2008f49a3596c6f8f8ecc2b5137119c772d42288b168eb82d1a88540250b9f3afff8f2731898e19cffdd75657596a21c6cdb7497e4e
 DIST Shortwave-5.0.0.tar.bz2 831354 BLAKE2B 6781e826cf9b00069e4041a272d63e752d22799d2838fb04702d6f398a42308e10183d4d4648be300e097c3afe39e3ce14a0c88b82cbd39354ba8924389e3146 SHA512 7049e8ff3eb8f7273c8d721f620954c90bb428a06c2baee270d04e43eee5f4c9c06d405e6391f86b0a13dbd3c261fab1b86669012e62903702eaa7b497fafccd
+DIST Shortwave-5.1.0-crates.tar.xz 45927744 BLAKE2B 0e88d82ff0e56a8b85b3fa00338da1d2a75fcd4cca2c38557488a26b849d033a401256ec2347d8cc47f944bbfaa776f12871a33a4f97f775bfc0d8a519d1828e SHA512 66b2b486f1cfb9a78d1bc574f26a18eed8416d0b9e502746cd5c2838fac9747e48b115c528db85d08c28997125989dd898edc0c128df6d2ffb233e4f4f539bb6
+DIST Shortwave-5.1.0.tar.bz2 843853 BLAKE2B 18d562ea161359affa5c6c1b3c29712aa1f33415a6d48bda8ff4fed5408a929c7ebfa15f562bf2a38e13f6199790479a4dfcec754df56fb5d8e26e428db0047a SHA512 543a2f91b2f9df44466c98a35a5d83300274dbcf9b9aca1c2e6e4d3fd479d1f900312aa13539701e5dc9a34344d8a3a566ef6366542343a81e622d8a4092ed6a
@@ -0,0 +1,80 @@
+# Copyright 2025-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Autogenerated by pycargoebuild 0.15.0
+
+EAPI=8
+
+CRATES=""
+
+inherit cargo gnome2-utils meson optfeature
+
+DESCRIPTION="An internet radio player"
+HOMEPAGE="https://apps.gnome.org/Shortwave/"
+SRC_URI="
+	https://gitlab.gnome.org/World/Shortwave/-/archive/${PV}/Shortwave-${PV}.tar.bz2
+	https://github.com/puleglot/Shortwave/releases/download/${PV}/Shortwave-${PV}-crates.tar.xz
+"
+S="${WORKDIR}/Shortwave-${PV}"
+
+LICENSE="GPL-3+"
+# Dependent crate licenses
+LICENSE+="
+	Apache-2.0 Apache-2.0-with-LLVM-exceptions BSD-2 BSD Boost-1.0 ISC
+	MIT MPL-2.0 Unicode-3.0
+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	dev-db/sqlite:3
+	dev-libs/glib
+	dev-libs/gobject-introspection
+	dev-libs/openssl:0=
+	>=gui-libs/gtk-4.16
+	>=gui-libs/libadwaita-1.8
+	media-libs/glycin:2
+	media-libs/gst-plugins-bad
+	media-libs/gst-plugins-base
+	media-libs/gstreamer
+	media-libs/lcms:2
+	>=media-libs/libshumate-1.3
+	sys-libs/libseccomp
+"
+# Runtime deps:
+#  - media-libs/glycin-loaders - required for displaying station covers.
+#  - media-plugins/gst-plugins-meta[http] - required to successfully build a gsreamer
+#    pipeline, since most (all?) stations have http/https URLs.
+#  - media-plugins/gst-plugins-meta[pulseaudio] - preferred audiosink. Volume control
+#    is supported only with pulsesink.
+#  - media-plugins/gst-plugins-meta[vorbis] - needed for recording feature.
+#    Shortwave will crash after each played track if vorbisenc is unavailable.
+RDEPEND="
+	${DEPEND}
+	media-libs/glycin-loaders
+	media-plugins/gst-plugins-meta[http]
+	media-plugins/gst-plugins-meta[pulseaudio]
+	media-plugins/gst-plugins-meta[vorbis]
+"
+BDEPEND="
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+BUILD_DIR="${WORKDIR}/${P}-build"
+ECARGO_HOME=${BUILD_DIR}/cargo-home
+
+pkg_postinst() {
+	# Popular codecs used by radio stations
+	optfeature "AAC playback support" "media-plugins/gst-plugins-meta[aac]"
+	optfeature "MP3 playback support" "media-plugins/gst-plugins-meta[mp3]"
+	optfeature "Opus playback support" "media-plugins/gst-plugins-meta[opus]"
+
+	gnome2_schemas_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+	xdg_icon_cache_update
+}