dev-python/aiolimiter: new package, add 1.2.1

Signed-off-by: Pavel Sobolev <contact@paveloom.dev>

dev-python/aiolimiter/Manifest

@@ -0,0 +1 @@
+DIST aiolimiter-1.2.1.gh.tar.gz 64017 BLAKE2B 08a15abf62dc3ee50751fa59a62c9a75e16a665cd464198d5d878d039849ee8a8e28d8b3fbe51b2c00fb8e596c5e45d3d83e6c56bafb958449acecfa1b9b19c8 SHA512 69350c5a1b86e1d8b8fa4dab4dccd8e2d14dcec8d981bc8d205465465db0959cfc77420d4e9b616fb136f00823c4b62ac50bc59aeb2415e65245988d3e453770

dev-python/aiolimiter/aiolimiter-1.2.1.ebuild

@@ -0,0 +1,43 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="An efficient implementation of a rate limiter for asyncio"
+HOMEPAGE="
+	https://github.com/mjpieters/aiolimiter
+	https://pypi.org/project/aiolimiter/
+"
+SRC_URI="https://github.com/mjpieters/aiolimiter/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	test? ( dev-python/toml[${PYTHON_USEDEP}] )
+"
+
+EPYTEST_PLUGINS=( pytest-asyncio )
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i 's/"session"/session/' tox.ini || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	epytest -o addopts=
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	dodoc LICENSE.txt
+}

dev-python/aiolimiter/metadata.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <name>Pavel Sobolev</name>
+    <email>contact@paveloom.dev</email>
+  </maintainer>
+  <upstream>
+    <bugs-to>https://github.com/mjpieters/aiolimiter/issues</bugs-to>
+    <remote-id type="github">mjpieters/aiolimiter</remote-id>
+    <remote-id type="pypi">aiolimiter</remote-id>
+  </upstream>
+</pkgmetadata>