dev-java/microsoft-openjdk-bin: add 25.0.0

Signed-off-by: Robert Greener <dev@greener.sh>

dev-java/microsoft-openjdk-bin/Manifest

@@ -4,3 +4,5 @@ DIST microsoft-jdk-17.0.16-linux-aarch64.tar.gz 190029526 BLAKE2B e92bba811547e5
 DIST microsoft-jdk-17.0.16-linux-x64.tar.gz 191356664 BLAKE2B 68774b034ee63824d62e76c15dbfc77a1c5829a6d3f3e712f51b4aaac9f83d061afc7a6ce03530de81a870f431f1f576dd5ffffd179acc583a0aafeacf32fef6 SHA512 f5083ea940d5ed04947336dd6b30d2ef0685d16c47427bd5701117d6d38df7685def8f7c1b84beb7e0b8c9ec43f67ed255da7e60b742927b6b25e31061ce7ddc
 DIST microsoft-jdk-21.0.8-linux-aarch64.tar.gz 204455021 BLAKE2B 8ce57f7b8d1e30c626c5c5f0202456ad6c287ec3a77032b4f4583da9a1cf300b120269df47646d57ff45e5fd643e5634fdef090550e3b600fa950053a80b1ab6 SHA512 ab3533cd27af3467d326e2cf29e971a40fc09baf68976e83b12940c6c1a7079b3bb868d070a0b2e1e1a67a45fa4ef90d9bf40dc32c0f8db3ce9c8af5bbc881ed
 DIST microsoft-jdk-21.0.8-linux-x64.tar.gz 206261335 BLAKE2B ef367392387b9ffb749a1e96dcb42f4f299564b14e86eabc58b4e6864db01178dcfd4da7be165ca72ada54e612509c3ff26e2f315a4fc29d63848f9f06b13329 SHA512 e7ab118af13e331549ac9d8d07ba4f4d0ad35b547babbf3ceaf763270f83e9a3a490c668cc2141e6601ea792d65684ffa33a21869de08b088170c50d24ce6bd0
+DIST microsoft-jdk-25.0.0-linux-aarch64.tar.gz 222029954 BLAKE2B aa71fa40dc264c12d77bc9ff9830cbb8e3d68fb9ade7fdcfe2229215f0e6d2b86a8aff866fef28f88a46b240f18e055d9fc925fd7dca013e4875d752cf6be32b SHA512 441333e7fc458b1affd361c78bb6b0fd1d426992b3e11c36c3816cfc02b8b21707845c8a625ca6422511abe83ff3eec2fb8ef318b02c05b8a34669bddcb60379
+DIST microsoft-jdk-25.0.0-linux-x64.tar.gz 224192545 BLAKE2B 7be89381dc2d6ac48e8f799b7a7083639594d78b547f52ec57933b644cdbec87db31bdc6b37426c9f45b5ea600c42c07ab824aa3d4b0928acbe266a8f7c45510 SHA512 31216a5dfcd6382d93458544ec5fac667849b881a23ae1df8021bf901cde7187be7c3c7f69c85c10e373d2426ec68e58bb1b54385d5fe2543d87bba1b91df020

dev-java/microsoft-openjdk-bin/microsoft-openjdk-bin-25.0.0.ebuild

@@ -0,0 +1,99 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit java-vm-2 toolchain-funcs
+
+MY_PV=${PV/_p/+}
+DESCRIPTION="Prebuilt Java JDK binaries provided by Microsoft"
+HOMEPAGE="https://www.microsoft.com/openjdk"
+
+SRC_URI="
+	amd64? ( https://aka.ms/download-jdk/microsoft-jdk-${PV}-linux-x64.tar.gz )
+	arm64? ( https://aka.ms/download-jdk/microsoft-jdk-${PV}-linux-aarch64.tar.gz )
+"
+
+S="${WORKDIR}/jdk-25+36"
+LICENSE="GPL-2-with-classpath-exception"
+SLOT=$(ver_cut 1)
+KEYWORDS="~amd64"
+IUSE="alsa cups headless-awt selinux source"
+
+DEPEND="
+	app-eselect/eselect-java
+"
+RDEPEND="
+	>=sys-apps/baselayout-java-0.1.0-r1
+	kernel_linux? (
+		media-libs/fontconfig:1.0
+		media-libs/freetype:2
+		media-libs/harfbuzz
+		elibc_glibc? ( >=sys-libs/glibc-2.2.5:* )
+		elibc_musl? ( sys-libs/musl )
+		sys-libs/zlib
+		alsa? ( media-libs/alsa-lib )
+		cups? ( net-print/cups )
+		selinux? ( sec-policy/selinux-java )
+		!headless-awt? (
+			x11-libs/libX11
+			x11-libs/libXext
+			x11-libs/libXi
+			x11-libs/libXrender
+			x11-libs/libXtst
+		)
+	)"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+pkg_pretend() {
+	if [[ "$(tc-is-softfloat)" != "no" ]]; then
+		die "These binaries require a hardfloat system."
+	fi
+}
+
+src_install() {
+	local dest="/opt/${P}"
+	local ddest="${ED}/${dest#/}"
+
+	# Not sure why they bundle this as it's commonly available and they
+	# only do so on x86_64. It's needed by libfontmanager.so. IcedTea
+	# also has an explicit dependency while Oracle seemingly dlopens it.
+	rm -vf lib/libfreetype.so || die
+
+	# prefer system copy # https://bugs.gentoo.org/776676
+	rm -vf lib/libharfbuzz.so || die
+
+	# Oracle and IcedTea have libjsoundalsa.so depending on
+	# libasound.so.2 but AdoptOpenJDK only has libjsound.so. Weird.
+	if ! use alsa ; then
+		rm -v lib/libjsound.* || die
+	fi
+
+	if use headless-awt ; then
+		rm -v lib/lib*{[jx]awt,splashscreen}* || die
+	fi
+
+	if ! use source ; then
+		rm -v lib/src.zip || die
+	fi
+
+	rm -v lib/security/cacerts || die
+	dosym -r /etc/ssl/certs/java/cacerts "${dest}"/lib/security/cacerts
+
+	dodir "${dest}"
+	cp -pPR * "${ddest}" || die
+
+	# provide stable symlink
+	dosym "${P}" "/opt/${PN}-${SLOT}"
+
+	java-vm_install-env "${FILESDIR}"/${PN}.env.sh
+	java-vm_set-pax-markings "${ddest}"
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}
+
+pkg_postinst() {
+	java-vm-2_pkg_postinst
+}