media-sound/yandex-music: 5.77.1 version bump

Signed-off-by: Sergey Torokhov <torokhov-s-a@yandex.ru>
2026-04-07 03:10:15 -04:00 · 2025-11-23 14:45:50 +03:00
parent a770a6d6f1
commit 4081677a23
2 changed files with 130 additions and 0 deletions
--- a/media-sound/yandex-music/Manifest
+++ b/media-sound/yandex-music/Manifest
@@ -1,2 +1,3 @@
 DIST Yandex_Music_amd64_5.75.2.deb 90330712 BLAKE2B ea605c24ceff469d86e43a654a1cf4cd5f8922616087899b7fc34a237d148883e22e0798e7d516a2fed892fa5f1a47207232b2149b625611d9d2d0cd82d42171 SHA512 384afaed7e1f334eb63c0d698de7aec626b5a29d0efcd975901ba76be68e3fe131c2070e0d81796fe99611ab8b37b655bdfa8d89cbdcdc3067f4ad160273ffd5
 DIST Yandex_Music_amd64_5.76.4.deb 90331836 BLAKE2B b332956da0c859aa96529e2d3e274ddcef443b3c1a919a0bc07570083dc72b7a1d13725b7cf347f58136492a5743c97d1b4c651309367f43736520d4834fc7b4 SHA512 c8f58adf2a8ea85eaa33018d34947fee30413fe087258aa47bcd352e03f78d852a2402c12b1ac7761a1571b2225c7eaf5ff8acecb13e2bae6696b0b01b232111
+DIST Yandex_Music_amd64_5.77.1.deb 92578104 BLAKE2B 1376879b0797dde63a6153a37b3c8859bbe2f3824fcb9e95bde11bf77aa335a939c6c0287a3463df62a7a2d06e002ab310b832252e13b6421db54be26883429e SHA512 5cb286cd7af5cac3ad15e7582d682170a30d5100e894ae12dc0fdbc97c443dc0c9af0ba689cad631cbac851c4aff753cf1b2aba91e37496d04016250be067fd8
--- a/media-sound/yandex-music/yandex-music-5.77.1.ebuild
+++ b/media-sound/yandex-music/yandex-music-5.77.1.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="af am ar bg bn ca cs da de el en-GB en-US es-419 es et fa fi fil fr gu he hi hr hu id it ja kn ko \
+lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr sv sw ta te th tr uk ur vi zh-CN zh-TW"
+inherit chromium-2 pax-utils wrapper unpacker xdg
+
+MY_PN="${PN/-/}"
+
+DESCRIPTION="Yandex Music streaming service"
+HOMEPAGE="https://music.yandex.ru/"
+SRC_URI="
+	amd64? ( https://music-desktop-application.s3.yandex.net/stable/Yandex_Music_amd64_${PV}.deb )
+"
+
+S="${WORKDIR}"
+
+LICENSE="Yandex-EULA"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-core
+	app-arch/bzip2
+	dev-libs/expat
+	dev-libs/fribidi
+	dev-libs/glib:2
+	dev-libs/gmp
+	dev-libs/libffi
+	dev-libs/libpcre2
+	dev-libs/libtasn1
+	dev-libs/libunistring
+	dev-libs/nettle
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	media-gfx/graphite2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/harfbuzz
+	media-libs/libepoxy
+	media-libs/libjpeg-turbo
+	media-libs/libpng
+	media-libs/mesa
+	net-dns/libidn2
+	net-libs/gnutls
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/systemd-utils
+	sys-apps/util-linux
+	sys-devel/gcc
+	sys-libs/glibc
+	sys-libs/libcap
+	virtual/zlib
+	x11-libs/cairo[X,glib]
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXdmcp
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/pango[X]
+	x11-libs/pixman
+"
+DEPEND="
+	>=dev-util/patchelf-0.9
+"
+
+QA_PREBUILT="*"
+QA_DESKTOP_FILE="usr/share/applications/yandex-music.*\\.desktop"
+YANDEX_HOME="opt/${PN}"
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	unpack_deb ${A}
+	mv -T "${S}/opt/Яндекс Музыка" "${S}/${YANDEX_HOME}" || die
+	mv -T "${S}/usr/share/doc/${MY_PN}" "${S}/usr/share/doc/${PF}" || die
+}
+
+src_prepare() {
+	default
+	sed -i -e "s|/opt/Яндекс Музыка/${MY_PN}|/opt/bin/${PN}|" -i -e "s/Audio;/AudioVideo;/" \
+		"${S}/usr/share/applications/${MY_PN}.desktop" || die
+
+	sed -i -e "s|/opt/Яндекс Музыка|/${YANDEX_HOME}|" "${S}/${YANDEX_HOME}"/resources/apparmor-profile || die
+
+	gunzip "usr/share/doc/${PF}/changelog.gz" || die "Failed to decompress docs"
+
+	rm "${S}/${YANDEX_HOME}"/resources/app-update.yml || die
+
+	pushd "${YANDEX_HOME}/locales" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	patchelf --remove-rpath "${S}/${YANDEX_HOME}/chrome-sandbox" || die "Failed to fix library rpath (chrome-sandbox)"
+	patchelf --remove-rpath "${S}/${YANDEX_HOME}/${MY_PN}" || die "Failed to fix library rpath (yandexmusic)"
+}
+
+src_install() {
+	insinto /opt
+	doins -r opt/*
+
+	insinto /usr
+	doins -r usr/*
+
+	make_wrapper ${PN} "/${YANDEX_HOME}/${MY_PN}" "" "/${YANDEX_HOME}" "/opt/bin/"
+
+	fowners root:root "/${YANDEX_HOME}/${MY_PN}"
+	fperms 4711 "/${YANDEX_HOME}/chrome-sandbox"
+	pax-mark m "${ED}${YANDEX_HOME}/chrome-sandbox"
+	fperms 755 "/${YANDEX_HOME}/${MY_PN}"
+}