media-gfx/swayimg: Bump to 4.6

Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr>

media-gfx/swayimg/Manifest

@@ -1,2 +1,3 @@
 DIST swayimg-4.3.tar.gz 785384 BLAKE2B 1d341b92865436b7cb1393e719a2e5fa3a69200a7cc4e2b0ce0d07564578245835951fd70bb186b3defaffc7765962694db8d73fa97b3721c2e2e992b7f6c38d SHA512 cdd9ee386fdc63f136ec91aa2750ffb67eb6b5a8b6751f75b7947a1793814d1ba81973ad7db19316d496cd6a355fc6288c326a042e8fe7f410e2a2346b2c6b57
 DIST swayimg-4.5.tar.gz 788904 BLAKE2B a92d8e439e0ca9d0b1a76e67bacc4a5489e9f90286c0bb6ca86e9934697e8b82dfde8b0c8190f709e9d318316035406ea55bfe6744c95e503eb2fb481b9332a8 SHA512 c193d3d3a56136279907138cfa832d1ec9991b17689949fb01150407591971bbf826a7898e23a5133905a25d2e35992bb45764e78c5844a8153771aab8ddbcdf
+DIST swayimg-4.6.tar.gz 791750 BLAKE2B 3c7859d82cb444acde6b018df64133b67447b7e730252249bfa6b3be4c0c6c984f109084846d92e58fa3f99689999c52570dfadd41fef73427ab05df0ce3e6aa SHA512 a2cd6f3a70b484e33a3f4d478ccda74f046b90622a2ce0c969f864c588358b38373f4755f29159295f4d368e28877536fca11d7c00ce9f83e99867a27d4d9e96

media-gfx/swayimg/swayimg-4.6.ebuild

@@ -0,0 +1,89 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+DESCRIPTION="Lightweight image viewer for Wayland display servers"
+HOMEPAGE="https://github.com/artemsen/swayimg"
+SRC_URI="https://github.com/artemsen/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="avif bash-completion drm exif exr gif heif jpeg jpegxl png raw sixel svg test tiff +wayland webp X"
+REQUIRED_USE="|| ( drm wayland )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	media-libs/fontconfig
+	media-libs/freetype
+	x11-libs/libxkbcommon
+	avif? ( media-libs/libavif:= )
+	bash-completion? ( app-shells/bash-completion )
+	drm? ( x11-libs/libdrm )
+	exif? ( media-libs/libexif )
+	exr? ( media-libs/openexr:= )
+	gif? ( media-libs/giflib:= )
+	heif? ( media-libs/libheif:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpegxl? ( media-libs/libjxl:= )
+	png? ( media-libs/libpng:= )
+	raw? ( media-libs/libraw:= )
+	sixel? ( media-libs/libsixel )
+	svg? (
+		dev-libs/glib:2
+		gnome-base/librsvg:2
+		x11-libs/cairo[X=]
+	)
+	tiff? ( media-libs/tiff:= )
+	wayland? (
+		dev-libs/json-c:=
+		dev-libs/wayland
+	)
+	webp? ( media-libs/libwebp:= )
+"
+DEPEND="${RDEPEND}
+	svg? ( X? ( x11-base/xorg-proto ) )
+	wayland? ( dev-libs/wayland-protocols )
+"
+BDEPEND="
+	test? ( dev-cpp/gtest )
+	wayland? ( dev-util/wayland-scanner )
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature avif)
+		$(meson_feature drm)
+		$(meson_feature exif)
+		$(meson_feature exr)
+		$(meson_feature gif)
+		$(meson_feature heif)
+		$(meson_feature jpeg)
+		$(meson_feature jpegxl jxl)
+		$(meson_feature png)
+		$(meson_feature raw)
+		$(meson_feature sixel)
+		$(meson_feature svg)
+		$(meson_feature test tests)
+		$(meson_feature tiff)
+		$(meson_feature wayland)
+		$(meson_feature wayland compositor)
+		$(meson_feature webp)
+		$(meson_feature bash-completion bash)
+		-Dversion=${PV}
+		-Ddesktop=true
+		# avoid automagic building with scdoc
+		-Dman=false
+		-Dzsh=enabled
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	doman extra/*.{1,5}
+}