app-text/simplenote-desktop-bin: add 2.23.2

Signed-off-by: Alexander Puck Neuwirth <alexander@neuwirth-informatik.de>

app-text/simplenote-desktop-bin/Manifest

@@ -1,2 +1,4 @@
 DIST simplenote-desktop-bin-2.23.0-amd64.deb 142363430 BLAKE2B 37897e85c355906e1767e639bb021e40370d6a28e69c94d3b91bee278b5a95bf24a99ac729d04eb5a55152413eba91b747e5cd9f48732f4b197699db42213d44 SHA512 fd061dd24fbcd53a0ac385c5c5150e64ac3df0126d07f83d3fc5faa672a07991036bb3bed617ac190f559edf6c9f3e02ca28ffc50da00bf8d3c5688c64ff4c47
 DIST simplenote-desktop-bin-2.23.0-arm64.deb 142682278 BLAKE2B 2bdeb64044d8eb34dfeab6527a8e53adf4e16f9390df24c02396e9f17e08baa2270d2247c210ebcc64f2433347be24b41d82f3e50f320c8c7ab230302cad89d2 SHA512 56416b2d6548e6b36bca4c81cf2f6add072372b8ec287f2676116e478651c2e940399857a500cf19a8e5e61b31d4bac4de536621fdc2e90e4a56be1c9b87de2c
+DIST simplenote-desktop-bin-2.23.2-amd64.deb 144376950 BLAKE2B 35397a614687b53132ee41f190ee0f8ee20ceded24c81753998271199e1c1aa5434bfde8aa6ce1cd30b93a0d5075d58885fdbab5541434a25c7ed886ad6857a9 SHA512 d3104ed1a8cd1b03043fda8d1d7984cf7827fe4eabdeef46a2dbbea9ab96c8026c561de57f2d0a5ff5c2d706ca58c969dd9e0d91e4cd1e2adb73476a6963380a
+DIST simplenote-desktop-bin-2.23.2-arm64.deb 149359336 BLAKE2B 2f0c47055481b5d69ea121ac4a297d496f3c639848ff0bb3801234fe89b3e3ec0a5b0566d63eae2b9c4363d0408cda9f06b2c16b06828ffe2c7f1957f92974d2 SHA512 e5ffd855798691055a63b71f28cee1d9f74ccd204ccd89a14e09a3ef830583316d8b4cee7501ea1e7a6f1f2f69c89b0ee102744dc8441887982feccad9ccfe1c

app-text/simplenote-desktop-bin/simplenote-desktop-bin-2.23.2.ebuild

@@ -0,0 +1,105 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="
+	af am ar bg bn ca cs da de el en-GB en-US es es-419 et fa fi fil fr gu he hi
+	hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr sv
+	sw ta te th tr uk ur vi zh-CN zh-TW
+"
+
+inherit chromium-2 desktop unpacker xdg
+
+DESCRIPTION="The simplest way to keep notes"
+HOMEPAGE="https://simplenote.com"
+SRC_URI="
+	amd64? (
+		https://github.com/Automattic/simplenote-electron/releases/download/v${PV}/Simplenote-linux-${PV}-amd64.deb\
+			-> ${P}-amd64.deb
+	)
+	arm64? (
+		https://github.com/Automattic/simplenote-electron/releases/download/v${PV}/Simplenote-linux-${PV}-arm64.deb\
+			-> ${P}-arm64.deb
+	)
+"
+S="${WORKDIR}"
+
+LICENSE="
+	MIT BSD BSD-2 BSD-4 AFL-2.1 Apache-2.0 Ms-PL GPL-2 LGPL-2.1 APSL-2
+	unRAR OFL-1.1 CC-BY-SA-3.0 MPL-2.0 android public-domain all-rights-reserved
+"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~arm64"
+
+RESTRICT="bindist mirror"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libxkbcommon
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="opt/Simplenote/*"
+
+pkg_pretend() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_prepare() {
+	default
+	# cleanup languages
+	pushd "opt/Simplenote/locales" || die
+	chromium_remove_language_paks
+	popd || die
+}
+
+src_configure() {
+	chromium_suid_sandbox_check_kernel_config
+	default
+}
+
+src_install() {
+	for size in {64,128,512}; do
+		doicon -s ${size} "usr/share/icons/hicolor/${size}x${size}/apps/simplenote.png"
+	done
+
+	domenu usr/share/applications/simplenote.desktop
+
+	local DESTDIR="/opt/Simplenote"
+	pushd "opt/Simplenote" || die
+
+	exeinto "${DESTDIR}"
+	doexe chrome-sandbox chrome_crashpad_handler simplenote *.so*
+
+	insinto "${DESTDIR}"
+	doins *.pak *.bin *.json *.dat
+	insopts -m0755
+	doins -r locales resources
+
+	# Chrome-sandbox requires the setuid bit to be specifically set.
+	# see https://github.com/electron/electron/issues/17972
+	fperms 4755 "${DESTDIR}"/chrome-sandbox
+
+	dosym "${DESTDIR}"/simplenote /opt/bin/simplenote
+	popd || die
+}