games-arcade/taisei: add 1.4

Signed-off-by: Oliver Freyermuth <o.freyermuth@googlemail.com>

games-arcade/taisei/Manifest

@@ -1 +1,2 @@
+DIST taisei-1.4.tar.xz 219573588 BLAKE2B c5a3300f3274ccc13e1beef9eb673affc223d761dfb632d9b067bc7cf401c3ed0422a78e0dba5334ab003044dae2cb24efb892edc955ee417ebc6c0477617314 SHA512 5715fd7dca868a3987941f24e26fb8ddc507ca5cb4e3c6a2b9c021bc0742d164e6ff2410f7b8de85907baa90f2c4b34925ac1196b163474047bee60141befb86
 DIST taisei-v1.3.2.tar.xz 70481856 BLAKE2B 608b5db6f17e2693539ce0742a1812633e91e901b3935b9e54f91514827642334f6cb6f0217aff713f1ff9dd01d971ae895ac8c98b0360f254b52d3e49bfae61 SHA512 9304c082106dfa1ffcf6c8fb7333e64755b1246ef50b9f49d3e64d167eb15575ac667ca658b1d7e247582e164e703e5817384556dd633f5516670d975817717d

games-arcade/taisei/taisei-1.4.ebuild

@@ -0,0 +1,69 @@
+# Copyright 2019-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10,11} )
+
+inherit meson python-any-r1 xdg
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/taisei-project/taisei.git"
+else
+	SRC_URI="https://github.com/taisei-project/taisei/releases/download/v${PV}/${PN}-${PV}.tar.xz"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Clone of the Touhou series, written in C using SDL/OpenGL/OpenAL."
+HOMEPAGE="https://taisei-project.org/"
+LICENSE="MIT CC-BY-4.0 CC0-1.0 public-domain"
+SLOT="0"
+
+IUSE="doc lto zip"
+
+RDEPEND="
+	media-libs/freetype:2
+	media-libs/opusfile
+	>=media-libs/libpng-1.5
+	media-libs/libsdl2
+	media-libs/libwebp
+	media-libs/opusfile
+	app-arch/zstd
+	sys-libs/zlib
+	dev-libs/openssl:=
+	zip? ( dev-libs/libzip )
+"
+DEPEND="
+	${RDEPEND}
+	>=dev-libs/cglm-0.7.8
+"
+BDEPEND="
+	dev-util/meson
+	$(python_gen_any_dep '
+		dev-python/zstandard[${PYTHON_USEDEP}]
+	')
+	${PYTHON_DEPS}
+	doc? ( dev-python/docutils )"
+
+python_check_deps() {
+	python_has_version "dev-python/zstandard[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	# Path patching needed also without USE=doc (COPYING etc.)
+	sed -i "s/doc_path = join.*/doc_path = join_paths(datadir, \'doc\', \'${PF}\')/" \
+		meson.build || die "Failed changing doc_path"
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc docs)
+		$(meson_use lto b_lto)
+		$(meson_use zip vfs_zip)
+		-Dstrip=false
+		-Duse_libcrypto=true
+	)
+	meson_src_configure
+}