www-client/helium-bin: add 0.16.2.1

Signed-off-by: Jonas Frei <freijon@pm.me>

www-client/helium-bin/Manifest

@@ -4,3 +4,5 @@ DIST helium-bin-0.14.9.1-amd64.tar.xz 119406836 BLAKE2B dd9545a51c6dd89da7b809d9
 DIST helium-bin-0.14.9.1-arm64.tar.xz 113521480 BLAKE2B d3e4680e0c6df15eabbc4c36bdc30b1f840561abe17a6dbdb124c8ab96ad80d081b745329c61a5483ba592b1c08fc2283a0402f8aa34e5123533e0f743ee5dbc SHA512 52e8698a72cb496c64a78c17bc2a48aeb6300cb051cc16150cf38b625d4d096c23ed18cd8316fa720162c1df01aeae0a5abfe23778461b75aba424e9166e95aa
 DIST helium-bin-0.15.5.1-amd64.tar.xz 124709260 BLAKE2B b97f429eca88d2e29c945a3ba254c0ef3741c63b48b307c175101a72120203e8c98ec8c3aed99e1299eb0d6f419966821749099b111e7b0eda2b78bbed423fbc SHA512 b57c62f4d428f310046e71771966d8fa2ac9e5914e9d255f4c3c643abb5e47262913a20eb1d523132cbb95c7b06cc8aa52bcf51350c273c3cfa165c92d3257f5
 DIST helium-bin-0.15.5.1-arm64.tar.xz 118119940 BLAKE2B 76b717f6dc7748109dfcb0243edc7c0114a56005509cff84fe74c589d272162223acb00fcfe38cecd7a78cd36fac13057485725b92c58eb4fb6ac085eb246251 SHA512 dba9d001f54414e97c8da9273c00101dae9e834edfe572d6d0adaf02421204756dac0bf6350ed4beef70cac6586603bfaf9a5cd8e6b1f3e2d5867f52758a6a2a
+DIST helium-bin-0.16.2.1-amd64.tar.xz 126265860 BLAKE2B a1ea9e958a6bbc7fb8bb3d39afa60e05971d0548e092240ee696dc6b3b69a20147c0ab85d1299d2049492fff18e1894ee06668dae9bc44f45defa9ce94be1604 SHA512 e42ca079afbca14ade308602186097b176d208b1a72b92a14965854ab3d3106e81abb53c246d1fc8a839087b8aa04cf72a0f135be334ae10b7fd902e2d842a42
+DIST helium-bin-0.16.2.1-arm64.tar.xz 120204332 BLAKE2B d072becc54ab2c3fc4715802511578eaba31ea15efaddc97a8ff1ad584d050037daaba75413f0486b85286054bc2cde68d48b832ba40009db4f024c2766b8be8 SHA512 b95754be5b2fa6bc9dcac318b539532efcd58807a8467bdc2498a699921f698ac60f298b4b767a126757d6b1cad87dcc7311766c6b9782dae898f99cfec11e83

www-client/helium-bin/helium-bin-0.16.2.1.ebuild

@@ -0,0 +1,114 @@
+# Copyright 2025-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="af am ar bg bn ca cs da de el en-GB en-US es-419 es
+	et fa fi fil fr gu he hi hr hu id it ja kn ko lt lv ml mr ms nb nl
+	pl pt-BR pt-PT ro ru sk sl sr sv sw ta te th tr uk ur vi zh-CN zh-TW"
+
+inherit chromium-2 desktop pax-utils xdg
+
+DESCRIPTION="Private, fast, and honest web browser based on Chromium"
+HOMEPAGE="https://helium.computer/"
+
+MY_PN="helium"
+MY_P="${MY_PN}-${PV}"
+
+if [[ ${ARCH} == amd64 ]] ; then
+	ARCH_TXT="x86_64"
+elif [[ ${ARCH} == arm64 ]] ; then
+	ARCH_TXT="${ARCH}"
+fi
+
+BASE_SRC_URI="https://github.com/imputnet/${MY_PN}-linux/releases/download/${PV}"
+SRC_URI="
+	amd64? ( ${BASE_SRC_URI}/${MY_P}-x86_64_linux.tar.xz -> ${P}-amd64.tar.xz )
+	arm64? ( ${BASE_SRC_URI}/${MY_P}-arm64_linux.tar.xz -> ${P}-arm64.tar.xz )
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-3 BSD"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~arm64"
+
+IUSE="qt6 selinux"
+
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-misc/ca-certificates
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	>=dev-libs/nss-3.26
+	media-fonts/liberation-fonts
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	sys-libs/libcap
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	|| (
+		x11-libs/gtk+:3[X]
+		gui-libs/gtk:4[X]
+	)
+	x11-libs/libdrm
+	>=x11-libs/libX11-1.5.0
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/pango
+	x11-misc/xdg-utils
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+	selinux? ( sec-policy/selinux-chromium )
+"
+
+QA_PREBUILT="*"
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+# Skip unpack, we're doing it during install
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir "opt" || die
+	cd "${ED}/opt/" || die
+
+	# Not possible to unpack to target folder, so: unpack, then mv
+	unpack "${P}-${ARCH}.tar.xz"
+	mv ${MY_P}-${ARCH_TXT}_linux ${MY_PN} || die
+
+	cd "${MY_PN}" || die
+
+	pushd "locales" > /dev/null || die
+	# Remove empty .info files
+	rm *.info || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	rm "libqt5_shim.so" || die
+	if ! use qt6; then
+		rm "libqt6_shim.so" || die
+	fi
+
+	newicon -s 256 "product_logo_256.png" ${MY_PN}.png
+	domenu "${FILESDIR}/${MY_PN}.desktop"
+	dobin "${FILESDIR}/${MY_PN}"
+
+	pax-mark m "${MY_PN}"
+}