mirror of
https://github.com/gentoo-mirror/guru.git
synced 2026-04-07 03:10:15 -04:00
app-containers/waydroid: add 1.5.2
Signed-off-by: Denis Reva <denis7774@gmail.com>
This commit is contained in:
Denis Reva
@@ -1,2 +1,3 @@
|
||||
DIST waydroid-1.4.3.tar.gz 240785 BLAKE2B e654f2ed74f8d22810417ee5d6f6134ee5050b4e105dd2c643fa39df660e8c325a80f8e75176dd65e052deba187890f8afd94c384d707e0287027d3454a533ea SHA512 e94edeca7097cb1572296d0b6e308483b1bd21e1bd50d9e6d2bd54d4ba75ffeb8bd4e1d1f8143fbcf49dddd30155da2e3c5a58240a85b159dae4e71985e547aa
|
||||
DIST waydroid-1.5.1.tar.gz 241421 BLAKE2B 0368304d2088f8920d3dd65cd7fcb9d9517097146b543d838219f337f55444e32d10e2dfc4d0ec2570268959f005686cc3a756c8a44cb89bd87a473cf40a05d1 SHA512 fde8c699fdd67d49ee355c96dbba5c94ce2061c280bb28533035982cd460335f93cd9350de90b525d286f72bd3e4bad73a341fca31909e9623553e9280fe7463
|
||||
DIST waydroid-1.5.2.tar.gz 241865 BLAKE2B 39ba1f759a9420fa92d02ea289cedfb8342e680ff57b304df3b94772991564d8385b8b722f2061dd1e0e9a40e0aa6aab52b6de5d3fc60e69a93d75b387693549 SHA512 80be97409d73c3dc649482ff9b8a9b3c316f7cfa7560c87e26a2b68a0efdcaa34c070825334789b6830e3ee0a88eb0967e9101575e4eadc4a39bda099c0f7651
|
||||
|
||||
110
app-containers/waydroid/waydroid-1.5.2.ebuild
Normal file
110
app-containers/waydroid/waydroid-1.5.2.ebuild
Normal file
@@ -0,0 +1,110 @@
|
||||
# Copyright 2022-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
PYTHON_COMPAT=( python3_{11..13} )
|
||||
inherit linux-info xdg python-single-r1
|
||||
|
||||
DESCRIPTION="Container-based approach to boot a full Android system on Linux systems"
|
||||
HOMEPAGE="https://waydro.id"
|
||||
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
|
||||
|
||||
LICENSE="GPL-3"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
|
||||
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
|
||||
IUSE="apparmor +clipboard systemd"
|
||||
|
||||
DEPEND="|| ( virtual/linux-sources virtual/dist-kernel )"
|
||||
RDEPEND="
|
||||
systemd? ( sys-apps/systemd )
|
||||
app-containers/lxc[systemd?,apparmor?,seccomp]
|
||||
$(python_gen_cond_dep '
|
||||
clipboard? ( >=dev-python/pyclip-0.7.0[wayland,${PYTHON_USEDEP}] )
|
||||
dev-python/pygobject[${PYTHON_USEDEP}]
|
||||
>=dev-python/gbinder-1.1.1[${PYTHON_USEDEP}]
|
||||
dev-python/dbus-python[${PYTHON_USEDEP}]
|
||||
')
|
||||
net-firewall/nftables
|
||||
net-dns/dnsmasq
|
||||
>=dev-libs/libglibutil-1.0.79
|
||||
>=dev-libs/gbinder-1.1.41
|
||||
${PYTHON_DEPS}
|
||||
"
|
||||
CONFIG_CHECK="
|
||||
~ANDROID_BINDER_IPC
|
||||
~ANDROID_BINDERFS
|
||||
~MEMFD_CREATE
|
||||
~NETFILTER_XT_TARGET_MASQUERADE
|
||||
~NETFILTER_XT_NAT
|
||||
~PSI
|
||||
~!PSI_DEFAULT_DISABLED
|
||||
~NF_TABLES
|
||||
~NF_TABLES_INET
|
||||
~NF_TABLES_NETDEV
|
||||
~NFT_NUMGEN
|
||||
~NFT_NAT
|
||||
~NFT_TUNNEL
|
||||
~NFT_QUOTA
|
||||
~NFT_SOCKET
|
||||
~NF_FLOW_TABLE
|
||||
~NFT_BRIDGE_META
|
||||
~NFT_BRIDGE_REJECT
|
||||
"
|
||||
ERROR_ANDROID_BINDERFS="CONFIG_ANDROID_BINDERFS: need for creating Android-specific binder IPC channels"
|
||||
ERROR_ANDROID_BINDER_IPC="CONFIG_ANDROID_BINDER_IPC: need for creating Android-specific binder IPC channels"
|
||||
ERROR_MEMFD_CREATE="CONFIG_MEMFD_CREATE: it completely replaced deprecated ISHMEM drivers,
|
||||
therefore it's vital for android-specific memory management"
|
||||
ERROR_NETFILTER_XT_NAT="CONFIG_NETFILTER_XT_NAT: see bug #937106"
|
||||
ERROR_NETFILTER_XT_TARGET_MASQUERADE="CONFIG_NETFILTER_XT_TARGET_MASQUERADE: see bug #937106"
|
||||
ERROR_PSI="CONFIG_PSI: see bug #947280"
|
||||
ERROR_NF_TABLES="CONFIG_NF_TABLES: Make sure you have NFTABLES up and running in your kernel"
|
||||
ERROR_NFT_NAT="CONFIG_NFT_NAT: see bug #947280"
|
||||
ERROR_NFT_BRIDGE_META="CONFIG_NFT_BRIDGE_META: see bug #947280"
|
||||
|
||||
pkg_setup() {
|
||||
linux-info_pkg_setup
|
||||
python-single-r1_pkg_setup
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
if ! use apparmor; then
|
||||
# https://github.com/waydroid/waydroid/issues/652
|
||||
sed -e '/^lxc\.apparmor\.profile =/d' \
|
||||
-i data/configs/config_3 || die
|
||||
fi
|
||||
default
|
||||
}
|
||||
|
||||
src_install() {
|
||||
python_fix_shebang waydroid.py
|
||||
emake install DESTDIR="${D}" USE_NFTABLES=1 USE_SYSTEMD=$(usex systemd 1 0)
|
||||
if ! use systemd; then
|
||||
elog "Installing waydroid OpenRC daemon"
|
||||
doinitd "${FILESDIR}"/waydroid
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
xdg_pkg_postinst
|
||||
|
||||
elog "After package installation run either 'emerge --config app-containers/waydroid'"
|
||||
elog "or 'waydroid init' from root shell to install android container runtime"
|
||||
elog "To run waydroid, 1. Start container: 'rc-service waydroid start'"
|
||||
elog "2. start wayland channel (from user shell) 'waydroid session start'"
|
||||
elog "Contact https://docs.waydro.id/usage/install-on-desktops for how-to guides"
|
||||
elog "(does not cover Gentoo-specific things sadly)"
|
||||
elog
|
||||
ewarn "Make sure you have NFTABLES up and running in your kernel. See"
|
||||
ewarn "https://wiki.gentoo.org/wiki/Nftables for how-to details"
|
||||
ewarn
|
||||
if use apparmor; then
|
||||
ewarn "Check the known issues for apparmor:"
|
||||
ewarn "https://docs.waydro.id/debugging/known-issues"
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_config() {
|
||||
"${EROOT}"/usr/bin/waydroid init
|
||||
}
|
||||
Reference in New Issue
Block a user