From d56345ab4e4fc238a87eb134008fbe28003b3f22 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?zyxhere=F0=9F=92=AD?= <zyx@envs.net>
Date: Wed, 21 Jan 2026 03:43:03 +0000
Subject: [PATCH] dev-build/buildstream-plugins: new package, add 2.7.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Part-off: https://codeberg.org/gentoo/guru/pulls/17
Signed-off-by: zyxhere💭 <zyx@envs.net>
---
 dev-build/buildstream-plugins/Manifest        |  1 +
 .../buildstream-plugins-2.7.0.ebuild          | 75 +++++++++++++++++++
 dev-build/buildstream-plugins/metadata.xml    | 11 +++
 3 files changed, 87 insertions(+)
 create mode 100644 dev-build/buildstream-plugins/Manifest
 create mode 100644 dev-build/buildstream-plugins/buildstream-plugins-2.7.0.ebuild
 create mode 100644 dev-build/buildstream-plugins/metadata.xml

diff --git a/dev-build/buildstream-plugins/Manifest b/dev-build/buildstream-plugins/Manifest
new file mode 100644
index 0000000000..466dbf0dfb
--- /dev/null
+++ b/dev-build/buildstream-plugins/Manifest
@@ -0,0 +1 @@
+DIST buildstream-plugins-2.7.0.tar.gz 125853 BLAKE2B 3ca7f1af10c0d649eaecb42602c5e0940c82209e546afcc0cdf32f110a778c6f524cf0bfbf99ff26d0e86916a0e1b2b9de57cbab9376f049381e841306bd3eb2 SHA512 2cd34d78ec7efe91d462eea12b48f9286349d1e07406258f564acf1de5d9736d6e2531cf401379212991060b935b19bf031d6f97e849446b0fdbf589c902c57a
diff --git a/dev-build/buildstream-plugins/buildstream-plugins-2.7.0.ebuild b/dev-build/buildstream-plugins/buildstream-plugins-2.7.0.ebuild
new file mode 100644
index 0000000000..0dd1e5e6c8
--- /dev/null
+++ b/dev-build/buildstream-plugins/buildstream-plugins-2.7.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="A collection of plugins for the BuildStream project."
+HOMEPAGE="https://apache.github.io/buildstream-plugins/"
+SRC_URI="
+	https://github.com/apache/buildstream-plugins/archive/refs/tags/${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="2"
+KEYWORDS="~amd64"
+IUSE="test"
+
+RDEPEND="
+	dev-build/buildstream:2[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		dev-python/pycodestyle[${PYTHON_USEDEP}]
+		dev-python/pyftpdlib[${PYTHON_USEDEP}]
+		dev-python/pylint[${PYTHON_USEDEP}]
+		dev-python/pytest-datafiles[${PYTHON_USEDEP}]
+		dev-python/pytest-env[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+RESTRICT="!test? ( test )"
+
+EPYTEST_PLUGINS=( pytest-datafiles )
+distutils_enable_tests pytest
+
+python_test() {
+	# UNKNOWN:Path name should not have more than 107 characters
+	local TMPDIR=/tmp
+
+	# fuse: failed to open /dev/fuse: Permission denied
+	addwrite "/dev/fuse"
+	# still fails inside a bubblewrap container :/
+	# fusermount3: mount failed: Operation not permitted
+
+	local EPYTEST_DESELECT=(
+		# fuse tests
+		tests/sources/cargo.py::test_cargo_track_fetch_build
+		tests/sources/patch.py::test_stage_and_patch
+		tests/sources/patch.py::test_stage_file_nonexistent_dir
+		tests/sources/patch.py::test_stage_file_empty_dir
+		tests/sources/patch.py::test_stage_separate_patch_dir
+		tests/sources/patch.py::test_stage_multiple_patches
+		tests/sources/patch.py::test_patch_strip_level
+		# tests using network
+		tests/sources/docker.py::test_docker_fetch
+		tests/sources/docker.py::test_docker_source_checkout
+		tests/sources/docker.py::test_handle_network_error
+		tests/sources/docker.py::test_fetch_duplicate_layers
+		source_determinism.py::test_deterministic_source_umask[git]
+	)
+
+	# to not pollute the source directory and make grepping hard.
+	# can't just use ${T} as the --basetemp option removes the directory
+	# if it exists
+	epytest --basetemp "${T}"/test_dir
+}
diff --git a/dev-build/buildstream-plugins/metadata.xml b/dev-build/buildstream-plugins/metadata.xml
new file mode 100644
index 0000000000..c91e42bbb4
--- /dev/null
+++ b/dev-build/buildstream-plugins/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>zyx@envs.net</email>
+    <name>zyxhere💭</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">apache/buildstream-plugins</remote-id>
+  </upstream>
+</pkgmetadata>