sys-auth/authenticator: new package, add 4.6.2

Signed-off-by: Pavel Sobolev <contact@paveloom.dev>

sys-auth/authenticator/Manifest

@@ -0,0 +1,2 @@
+DIST authenticator-4.6.2-deps.tar.xz 51491068 BLAKE2B 7f18b40f78c022b5c4493e33c30ebc096986e2cb54374f6dcc9232c7705322271fe35926102fd2d5530e5ab2e44f6e26972ce4e5b26930250b1c116c37e6a590 SHA512 87253659234035c0a4ab55ea6049543fee368fc2d68c7ae683d83310b93e7e5a7848d53d9bf681c97ae4498c1feb968c648bd36db3664d4b4212f69f74e1beb2
+DIST authenticator-4.6.2.tar.bz2 723559 BLAKE2B 135e9dbd237da4da74c68186112bac56f4e38158638788f24894654c18b71cfbb7b8a4a8e6f93f0783211fae640e7085a9ae4dd4bf7c17d70d1ab33889fe908a SHA512 d55c2ba5ef0cdc6b93092a34ee98e1303cb5d8c8a8978d740a932ea0b992f45b599796306f0b7cce8a89a7adc91e2c36099525b9f52ba5b0bfbbe971acf57f52

sys-auth/authenticator/authenticator-4.6.2.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cargo gnome2-utils meson xdg
+
+DESCRIPTION="2FA code generator for GNOME"
+HOMEPAGE="https://gitlab.gnome.org/World/Authenticator"
+SRC_URI="
+	https://gitlab.gnome.org/World/Authenticator/-/archive/${PV}/Authenticator-${PV}.tar.bz2 -> ${P}.tar.bz2
+	https://gitlab.com/api/v4/projects/69517529/packages/generic/${PN}/${PV}/${P}-deps.tar.xz
+"
+
+S="${WORKDIR}/Authenticator-${PV}"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="debug test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	gui-libs/gtk:4
+	gui-libs/libadwaita:1
+	media-libs/gst-plugins-base:1.0
+	media-libs/gstreamer:1.0
+	media-plugins/gst-plugin-gtk4
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/appstream
+	dev-libs/glib:2
+	dev-util/desktop-file-utils
+	dev-util/gtk-update-icon-cache
+	sys-devel/gettext
+
+	debug? ( dev-vcs/git )
+"
+
+src_configure() {
+	local profile="default"
+	use debug && profile="development"
+
+	local emesonargs=(
+		-Dprofile="$profile"
+	)
+	meson_src_configure
+
+	ln -s "${CARGO_HOME}" "${BUILD_DIR}/cargo-home" || die
+}
+
+src_test() {
+	cargo_src_test
+	meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}

sys-auth/authenticator/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>contact@paveloom.dev</email>
+    <name>Pavel Sobolev</name>
+  </maintainer>
+  <upstream>
+    <bugs-to>https://gitlab.gnome.org/World/Authenticator/-/issues</bugs-to>
+    <remote-id type="gnome-gitlab">World/Authenticator</remote-id>
+  </upstream>
+</pkgmetadata>