From 1ce51e577c6a02d396292a5377c2bec3cd0cca8d Mon Sep 17 00:00:00 2001
From: Florian Albrechtskirchinger <falbrechtskirchinger@gmail.com>
Date: Tue, 23 Jun 2026 14:14:17 +0200
Subject: [PATCH] dev-python/griffelib: add 2.1.0

Signed-off-by: Florian Albrechtskirchinger <falbrechtskirchinger@gmail.com>
---
 dev-python/griffelib/Manifest               |  1 +
 dev-python/griffelib/griffelib-2.1.0.ebuild | 50 +++++++++++++++++++++
 2 files changed, 51 insertions(+)
 create mode 100644 dev-python/griffelib/griffelib-2.1.0.ebuild

diff --git a/dev-python/griffelib/Manifest b/dev-python/griffelib/Manifest
index 6bb5c026f7..380ba83427 100644
--- a/dev-python/griffelib/Manifest
+++ b/dev-python/griffelib/Manifest
@@ -1 +1,2 @@
 DIST griffe-2.0.2.gh.tar.gz 432943 BLAKE2B b726fb17e34e5aa2a4e56f53be47369fca7cac1413394348cd2633ec2b70f554b58d52bc6791d7de98dae84d5740fd51c19548a5bd8aae695eb85fae1317b5ea SHA512 b13ae34a609fdd9ba258226d9d2306d355cabfc19631e0ee022501f635cd1c85b6c6c55432b3be1a29a17e1f36bd461e902f26a0b24ff12f82b1c42d7ac08b6b
+DIST griffe-2.1.0.gh.tar.gz 433747 BLAKE2B 004f5f2a8ecbba479e78bbec1ce035af4df6ede3be4351507942041fb544121b10094b6d596ed32c2a110877526f5966ea85ac29ff578cd1e53d34cccfc5903a SHA512 bc44c550356b80ceb333f6aa866b0fbd6d278fe43f69eb73b355835d2eb1e60c51a5a1c0630a44cdb086a2ffe2e0eb69f919561bbeb12a3ce95196ec40a23034
diff --git a/dev-python/griffelib/griffelib-2.1.0.ebuild b/dev-python/griffelib/griffelib-2.1.0.ebuild
new file mode 100644
index 0000000000..67c486be2e
--- /dev/null
+++ b/dev-python/griffelib/griffelib-2.1.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit distutils-r1
+
+MY_PN="griffe"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Signatures for entire Python programs"
+HOMEPAGE="
+	https://mkdocstrings.github.io/griffe
+	https://github.com/mkdocstrings/griffe
+	https://pypi.org/project/griffelib/
+"
+SRC_URI="https://github.com/mkdocstrings/${MY_PN}/archive/${PV}.tar.gz -> ${MY_P}.gh.tar.gz"
+S="${WORKDIR}/${MY_P}/packages/griffelib"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+# pdm-backend is used by scripts/get_version.py
+BDEPEND="
+	dev-python/pdm-backend[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/jsonschema-4.18[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# requires mkdocstrings
+	tests/test_api.py
+	# requires griffecli
+	tests/test_git.py
+)
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# docs/schema.json for tests/test_encoders.py
+	ln -s ../../docs || die
+}